Tisk do souboru (MB02 only)

Zdrojový kód

         org  23296



INIT
         ld   hl,CHANNEL3
         ld   (23749),hl
         ld   hl,16384
         ld   (CHANNEL3+1),hl
         xor  a
         ld   (LAST+1),a
         ret


CHANNEL3
         ld   hl,16384
         ld   (hl),a
         cp   "|"
         jr   nz,SKIP

LAST     cp   0
         jr   z,KONEC

SKIP
         cp   13
         ld   (LAST+1),a
         call z,PACK
         inc  hl
         ld   (CHANNEL3+1),hl
         ld   a,h
         cp   23296/256
         ret  nz

KONEC
         ld   a,h
         cp   23296/256
         jr   z,KON1
         ld   (hl),0
         inc  hl
         jr   KONEC

KON1
         call #3C9E

         ld   ix,HEAD
         ld   a,#26
         rst  32

         ld   ix,16384
         ld   bc,0
         ld   e,7
         ld   a,#25
         rst  32

         call #3C98

         ld   a,(CISLO+1)
         inc  a
         cp   "9"+1
         jr   nz,OKI

         ld   a,(CISLO)
         inc  a
         ld   (CISLO),a
         ld   a,"0"
OKI
         ld   (CISLO+1),a

         jr   INIT


PACK
         dec  hl
         ld   a,(hl)
         cp   32
         jr   z,PACK
         inc  hl
         ld   (hl),13
         inc  hl
         ld   (hl),10
         ret



HEAD     defb 176

         defb 0
         defb 0
         defb 0
         defb 0

         defb 3

         defm "PRN_FILE"
CISLO    defb "0"
         defb "0"

         defb 0
         defb 27

         defb 0
         defb 64

         defb 0
         defb 128


         defb 0
         defb 64

         defb 0
         defb 27
         defb 0
         defb 0

         defb 255

         defb 0

         defb 0
         defb 0


A1_END   equ  $-23296

;|



Popis
Po spuštění se připojí na kanál #3 a ukončí se. Při zápisu na kanál #3 (tiskárnu) ukládá data do obrazovky. Mezery na konci řádku se vypouštějí a odřádkování se převádí na PC formát. Po zaplnění obrazovky se soubor uloží a začíná se plnit znovu. Tisk bude ukončen po vyhodnocení sekvence ;||

Poznámky
Pouze pro MB02

Poslal
dR0n_K3l